Récupération d’information d’inventaire dans Excel par du VBscript et des objets WMI

Je vous propose un petit script, en VBScript, il permet de lire des objets WMI en VB et de les écrire dans Microsoft Excel. Ce script permet de récupérer des informations en vue d’une utilisation dans un atelier ou en déplacement si vous n’avez pas de gestionnaire de parc. Il récupère les éléments WMI et Security Center (1 et 2)

const HKEY_CURRENT_USER = &H80000001
const HKEY_LOCAL_MACHINE = &H80000002
' déclaration de deux constantes pour récupéré
' le nom de l'utilisateur
strComputer = "."
'les objets WMI proviennent de la machine locale
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
& strComputer & "\root\default:StdRegProv")
'on déclare la variable oReg pour récupéré les infos dans l'arboresence WMI
strKeyPath = "SOFTWARE\Microsoft\Windows NT\CurrentVersion\Winlogon"
'Chemin d'acces au nom de l'utilisateur dans la Base des Registres
strValueName = "DefaultUserName"
'Valeur que l'on recherche dans la base des registre
'(le nom de l'utilisateur par défaut)
oReg.GetStringValue HKEY_LOCAL_MACHINE, strKeyPath, strValueName, strValue
x=2
Set objExcel = CreateObject("Excel.Application")
objExcel.Visible = True
' On le définit comme visible
Set objWorkbook = objExcel.Workbooks.Add()
'on ajoute un classeur
Set objWorksheet = objWorkbook.Worksheets(1)
strEntreprise = "Etienne Deneuve"
'on ajoute une feuille de calcul
' on défini que x est égal a 2 pour la suite
objExcel.Cells(1, 1).Value = strEntreprise
objExcel.Cells(1, 1).Font.Size = 12
objWorksheet.Range(objExcel.Cells(1, 1), objExcel.Cells(1, 8)).Merge
objExcel.Cells(2, 1).Value = "Machine :" '3,2
objExcel.Cells(2, 3).Value = "Model :" '6.2
objExcel.Cells(2, 5).Value = "Fabricant :" '9.2
objExcel.Cells(4, 1).Value = "N° de Série :"
objExcel.Cells(4, 3).Value = "Mémoire :"
objExcel.Cells(4, 5).Value = "IP :"
objExcel.Cells(6, 1).Value = "Masque :" '3,2
objExcel.Cells(6, 3).Value = "Passerelle :" '6.2
objExcel.Cells(3, 1).Value = "Nom de Domaine :" '9.2
objExcel.Cells(8, 1).Value = "Disque dur :"
objExcel.Cells(8, 3).Value = "Anti-Virus :"
objExcel.Cells(8, 5).Value = "Pare Feu :"
objExcel.Cells(11, 1).Value = "OS :"
objExcel.Cells(11, 3).Value = "Dernier Service Pack :"
objExcel.Cells(11, 5).Value = "Licence Windows :"

Set objWMIService = _
GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
'on défini l'objet objWMIService comme chemin de base dans l'ordinateur
'local dans la classe ROOT\cimv2
Set colItems = objWMIService.ExecQuery("Select * from Win32_ComputerSystem")
'on defini un tableau dont les objets de la colonne principal provient
'de la classe Win32_ComputerSystem
For Each objItem in colItems
'Boucle pour lire chaque objet de la classe
objWorksheet.Cells(2, 2) = ObjItem.Name
' ecrit dans la cellule le nom de l'ordinateur
objWorksheet.Cells(2 ,4) = objItem.Model
'ecrit le model de l'ordinateur
objWorksheet.Cells(4 ,4).Value = FormatNumber( _
objItem.TotalPhysicalMemory / 1048576,1,false,true,true) & " Mo"
' ecrit la quantité de mémoire Ram installé dans l'ordinateur
Next
' fin de la boucle
Set ColItems = objWMIService.ExecQuery("Select * from Win32_ComputerSystemProduct")
' on défini une nouvelle colonne dans le tableau dont les valeurs proviennent de
' la classe Win32_ComputerSystemProduct
For Each objItem in colItems
'Nouvelle boucle
objWorksheet.Cells(2 ,6).Value = objItem.Vendor
'on écrit le nom du fabricant dans la cellule
Next
'fin de la boucle
Set colItems = objWMIService.ExecQuery( _
"SELECT * FROM Win32_NetworkAdapterConfiguration", "WQL", _
wbemFlagReturnImmediately + wbemFlagForwardOnly)
' encore un appel d'un objet mais plus spécifique celui ci,
' il va nous permettre de lire la configuration réseau de la machine

'faire une incrémentation de i
'If i = 1 Then
'si i est égal a 1 alors
x=4
y=6
z=6
Set colAdapters = objWMIService.ExecQuery _
("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")
For Each objAdapter in colAdapters
If Not IsNull(objAdapter.IPAddress) Then

For i = 0 To UBound(objAdapter.IPAddress)
objWorksheet.Cells(x, 6).Value =  objAdapter.IPAddress(i)
x=x+1
Next
End If

If Not IsNull(objAdapter.IPSubnet) Then

For i = 0 To UBound(objAdapter.IPSubnet)
objWorksheet.Cells(y, 4).Value = objAdapter.IPSubnet(i)
y=y+1
Next
End If

If Not IsNull(objAdapter.DefaultIPGateway) Then

For i = 0 To UBound(objAdapter.DefaultIPGateway)
objWorksheet.Cells(z, 2).Value = objAdapter.DefaultIPGateway(i)
z=z+1
Next
End If

Next

Set colSerial = objWMIService.ExecQuery("SELECT * FROM Win32_BaseBoard", "WQL", _
wbemFlagReturnImmediately + wbemFlagForwardOnly)
For Each objSerial In colSerial
objWorkSheet.Cells(4, 2).Value = objSerial.SerialNumber
Next

Set colDisk = objWMIService.ExecQuery("Select * From Win32_LogicalDisk ", "WQL", _
wbemFlagReturnImmediately + wbemFlagForwardOnly)
x = 8
For Each objDisk In colDisk
IF NOT objDisk.Size = "" Then
IF NOT FormatNumber(  objDisk.Size / 1073741824,0,false,true,true) = 1 OR FormatNumber(  objDisk.Size / 1073741824,0,false,true,true) = 5 THEN
objWorkSheet.Cells(x, 2).Value = FormatNumber(  objDisk.Size / 1073741824,0,false,true,true) & " Go"
x=x+1
end if
end if

Next
Set colSettings = objWMIService.ExecQuery _
("Select * from Win32_OperatingSystem")

For Each objOperatingSystem in colSettings

OSVersion = Left(objOperatingSystem.Version,3)
ProductType = objOperatingSystem.ProductType

'Time to convert numbers into names
Select Case OSVersion
Case "6.1"
OSName = "Windows 7"
objWorkSheet.Cells(11, 2).Value = OSName
Set oWMI = GetObject( _
"winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\SecurityCenter2")
Set colItems = oWMI.ExecQuery("Select * from AntiVirusProduct")
x=8
For Each objItem in colItems
objWorkSheet.Cells(x, 4).Value = objItem.displayName
x=x+1
Next
Set colItems = oWMI.ExecQuery("Select * from FirewallProduct")
For Each objItem in colItems
objWorkSheet.Cells(8, 6).Value = objItem.displayName
x=x+1
Next
Case "6.0"
OSName = "Windows Vista"
objWorkSheet.Cells(11, 2).Value = OSName
Set oWMI = GetObject( _
"winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\SecurityCenter2")
Set colItems = oWMI.ExecQuery("Select * from AntiVirusProduct")
x=8
For Each objItem in colItems
objWorkSheet.Cells(x, 4).Value = objItem.displayName
x=x+1
Next
Set colItems = oWMI.ExecQuery("Select * from FirewallProduct")
For Each objItem in colItems
objWorkSheet.Cells(8, 6).Value = objItem.displayName
Next
Case "5.2"
OSName = "Windows 2003"
Case "5.1"
OSName = "Windows XP"
objWorkSheet.Cells(11, 2).Value = OSName
Set oWMI = GetObject( _
"winmgmts:{impersonationLevel=impersonate}!\\" & strComputer & "\root\SecurityCenter")
Set colItems = oWMI.ExecQuery("Select * from AntiVirusProduct")
x=8
For Each objItem in colItems
objWorkSheet.Cells(x, 4).Value =  objItem.displayName & " " & objItem.versionNumber
x=x+1
Next
Case "5.0"
OSName = "Windows 2000"
Case "4.0"
OSName = "NT 4.0"
Case Else
OSName = "Windows ME ou +"
End Select

FindOSType = OSName
Next
Set WshShellKey = CreateObject("WScript.Shell")
Set WshNetworkKey = WScript.CreateObject("WScript.Network")
Set env = WshShellKey.environment("Process")

Set objWMIServiceKey = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Const UnInstPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\"
Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" &_
".\root\default:StdRegProv")
strDigitalProductId="HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"
objWorkSheet.Cells(11, 6).Value = GetKey(WshShellKey.RegRead(strDigitalProductId))

Function GetKey(rpk)

Const rpkOffset=52:i=28
szPossibleChars="BCDFGHJKMPQRTVWXY2346789"

Do 'Rep1
dwAccumulator=0 : j=14
Do
dwAccumulator=dwAccumulator*256
dwAccumulator=rpk(j+rpkOffset)+dwAccumulator
rpk(j+rpkOffset)=(dwAccumulator\24) and 255
dwAccumulator=dwAccumulator Mod 24
j=j-1
Loop While j>=0
i=i-1 : szProductKey=mid(szPossibleChars,dwAccumulator+1,1)&szProductKey
if (((29-i) Mod 6)=0) and (i<>-1) then
i=i-1 : szProductKey="-"&szProductKey
End If
Loop While i>=0 'Goto Rep1

GetKey=szProductKey
End Function

x = 13
'on défini x comme egal a 8 pour géré les lignes dans Excel
objWorksheet.Cells(12, 1).Value = "Programmes Installés :"
' on ecrit dans la ligne 7 juste avant 8
Set colSoftware = objWMIService.ExecQuery _
("Select * from Win32_Product")
' on récupère la classe Product
For Each objSoftware in colSoftware
REM ' pour chaque objet dans la colonne
objWorksheet.Range(objExcel.Cells(x, 1), objExcel.Cells(x, 8)).Merge
REM ' on fusionne la ligne pour la lisibilité
objWorkSheet.Cells(x, 1).Value = objSoftware.Name
REM ' on écrit le nom du programme installé
x = x+1
REM ' on incrémente x
Next
' on fini

Set objRange = objWorksheet.UsedRange
' on déclare l'objet objRange comme égal a la dernière ligne utilisée
objRange.EntireColumn.Autofit()
' on égalise la taille des colonnes

Vous mettez le tout dans le bloc-note sauvegarder avec une extension .vbs et voilà

Bonne lecture

PS: le script n’affiche rien pendant quelques minutes au moment de la lecture des programmes installés c’est normal